Bruker:Haros

no-N	Denne brukeren behersker norsk (bokmål) på morsmålsnivå.

en-3	This user has advanced knowledge of English.

nn-2	Denne brukaren meistrar nynorsk på eit middels nivå.

da-2	Denne bruger har et godt kendskab til dansk.

sv-2	Den här användaren har medelgoda kunskaper i svenska.

de-2	Dieser Benutzer beherrscht Deutsch auf fortgeschrittenem Niveau.

it-1	Questo utente può contribuire con un livello elementare in italiano.

Denne brukeren har vært på Wikipedia i
19 år, 4 måneder og 29 dager.

Denne brukeren er byråkrat på Wikipedia på bokmål og riksmål. (verifiser, alle)

Land jeg har besøkt

Lister

Komponister delt etter fødselsår
før 1500 - 1500-1600 - 1600-1650 - 1650-1700 - 1700-1750 - 1750-1800 - 1800-1850 - 1850-1900 - 1900-1925 - 1925-1950 - 1950-1975 -

Commons

Mine bilder på commons finnes på commons:Category:Pictures by User:Haros. Det er nå totalt 7 493 bilder.

Vi mangler fortsatt noen artikler før vi har dekket all menneskelig kunnskap. Svært mye av dette mangler vi dessuten bilder av.

Kinesisk fiskenot ved Kochi. Nettet er synlig på Google Earth og Google Maps på posisjonen 10°0′50″N 76°14′23″Ø
Commons Featured Picture.
En fisker i Keralas store «backwater»område
Commons Featured Picture.
Fra stranden i Puvar, Kerala
Commons Featured Picture.
Trapp i Alberta ielā 12, Riga
Commons Featured Picture.

Budhisttemplet Wat Mahathat i Luang Prabang i Laos
Commons Quality Image.

Malt tak i klosterkirken i Seitenstetten
Delt 16. plass i WLM 2011 Østerrike.
Detalj fra taket i Grote of Onze-Lieve-Vrouwekerk, Breda, Nederland.
6. plass i WLM 2012 Nederland
Taket i Liebfrauenkirche i Trier.
6. plass i WLM 2013 Tyskland
11. plass i den internasjonale finalen
Takfreske i kirken Mariä Himmelfahrt i Dillingen an der Donau.
16. plass i WLM 2014 Tyskland
Klosterbibliotek i klosteret i Bad Schussenried.
61. plass i WLM 2014 Tyskland

Wikidata - Nyttige søk

Byer med navn forskjellig på engelsk og bokmål

Dette søket bruker det som er gitt som etikett på Wikidata til å få en oversikt over byer som har et annet navn på engelsk enn på norsk. Byer som mangler etikett på norsk vil mangle fra dette søket og kan godt allikevel ha forskjellig navn.

Brukte elementer: by (Q515), Russland (Q159)

Brukte egenskaper: forekomst av (P31), underklasse av (P279), land (P17), geokoordinater (P625)

SELECT DISTINCT ?city ?cityLen ?cityLnb ?koord WHERE {
  ?city (wdt:P31/wdt:P279*) wd:Q515.
  ?city wdt:P17 wd:Q159.
  OPTIONAL {
    ?city wdt:P625 ?koord .
  }
  ?city rdfs:label ?cityLen.
  ?city rdfs:label ?cityLnb.
  FILTER((LANG(?cityLen)) = "en")
  FILTER((LANG(?cityLnb)) = "nb")
  FILTER((!CONTAINS(?cityLen, ?cityLnb)) && !CONTAINS(?cityLnb, ?cityLen))
}
ORDER BY ?identLabel
LIMIT 1000

Prøv!

Stortingsrepresentanter i en gitt stortingsperiode

Brukte elementer: menneske (Q5), stortingsrepresentant (Q9045502), stortingsperioden 1950–1953 (Q69504706)

Brukte egenskaper: forekomst av (P31), verv eller stilling (P39), etternavn (P734), parlamentsperiode (P2937), valgdistrikt (P768)

# Stortingsrepresentanter i en gitt stortingsperiode
# Finner alle stortingsrepresentanter som har verv (P39) som stortingsrepresentant (Q9045502),
# og som har kvalifikator med en gitt stortingsperiode (P2937) 
# Representanten returneres som wikitekst-lenke til artikkel med etternavnet som artikkeltekst.
# Lenken kan være rød.
# Valgdistriktet representanten ble valgt til returneres også, og listen er sortert etter denne.
select ?valgdistriktLabel ?representant
where
{
  SELECT ?etternavnLabel ?valgdistriktLabel 
  ?lenke ?lenke2 ?lenke3 
  (concat ("[[",str(?lenke3),"|",str(?etternavnLabel),"]]") as ?representant)
  WHERE 
  {
    ?item wdt:P31 wd:Q5;
          wdt:P39 wd:Q9045502.
    ?item p:P39 ?node .
    ?node ps:P39 wd:Q9045502 .
    ?node pq:P2937 wd:Q69504706 . ## her kan det byttes til nye stortingsperioder
    
    ?node pq:P768 ?valgdistrikt.
    ?item wdt:P734 ?etternavn.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "nb,en". } 
    optional {
      ?article schema:about ?item .
      ?article schema:isPartOf <https://no.wikipedia.org/>;
      schema:name ?articlename .
      bind (?articlename as ?lenke)
    }
    ?item rdfs:label ?lenke2 FILTER (lang(?lenke2) = "nb").
    BIND(
          IF (!BOUND(?lenke),  ?lenke2,?lenke)
      AS ?lenke3).
  
  } 
}
order by ?valgdistriktLabel

Prøv!

Brukte elementer: Norge (Q20), museum (Q33506)

Brukte egenskaper: forekomst av (P31), land (P17), geokoordinater (P625), underklasse av (P279), bilde (P18)

# Museums in Norway
# Colors represent the number of wiki articles for each item
# Adapted from
# Query by Andrea Mignone @i_m_andrea, original idea by Synapta @synapta
#defaultView:Map{"layer":"?linksBin", "rgb":"?rgb"}
SELECT *
WHERE {
  
    BIND(
        IF(?links = 0, "a) 0 wiki",
            IF(?links = 1, "b) 1 wiki",
                IF(?links <= 3, "c) [2;4) wikis",
                    "d) 4+ wikis")))
    AS ?linksBin)

    BIND(
        IF(?links = 0, "000000",
            IF(?links = 1, "ff0700",
                IF(?links <= 3, "ffa500",
                    "007f00")))
    AS ?rgb)
  
    {
        SELECT ?item ?itemLabel ?c ?image (count(?sitelink) as ?links)

        WHERE {
            SELECT ?item ?itemLabel ?sitelink (min(?coord) as ?c) (min(?img) as ?image) 
            WHERE {
                ?item wdt:P31 ?type ;
                        wdt:P17 wd:Q20 ;
                        wdt:P625 ?coord .
                ?type wdt:P279* wd:Q33506 .
                OPTIONAL {?item wdt:P18 ?img}
                OPTIONAL {?sitelink schema:about ?item .
                        FILTER REGEX(STR(?sitelink), ".wikipedia.org/wiki/") .
                        }
                
                SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],nb,en". }
            }
        GROUP BY ?item ?itemLabel ?sitelink
               
        }
        GROUP BY ?item ?itemLabel ?c ?image

    }
}
ORDER BY asc(?links)

Prøv!

Brukte egenskaper: ektefelle (P26), samboer (P451)

SELECT ?item ?itemLabel {SELECT ?item ?itemLabel ?p26 ?p451 WHERE { 
  ?item wdt:P26 ?p26 . 
  ?item wdt:P451 ?p451 .
    SERVICE wikibase:label { bd:serviceParam wikibase:language "nb". }

} 
}

Prøv!

Stortingsident og fødselsdato med referanse

Brukte egenskaper: stortingsrepresentant-ID (P3072), fødselsdato (P569), nevnt i (P248), referanse-URL (P854)

SELECT ?item ?itemLabel ?storting ?birth  ?ref ?refLabel ?refurl
WHERE
{
     ?item wdt:P3072 ?storting.
     ?item p:P569 ?statement.
     ?statement ps:P569 ?birth.
     ?statement prov:wasDerivedFrom ?refnode.
     OPTIONAL {?refnode   pr:P248 ?ref.}
     ?refnode   pr:P854 ?refurl.
     SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Prøv!

Biografier av norske statsborgere på no-wiki med dødsdato som har referanse på Wikidata

Brukte elementer: menneske (Q5), Norge (Q20)

Brukte egenskaper: forekomst av (P31), statsborgerskap (P27), dødsdato (P570), nevnt i (P248), referanse-URL (P854)

SELECT DISTINCT ?item ?itemLabel ?death ?article WHERE
{
SELECT ?item ?itemLabel ?death ?ref ?refLabel ?refurl ?article WHERE {
  ?item wdt:P31 wd:Q5.
  ?item wdt:P27 wd:Q20.
  ?sitelink schema:about ?item.
  ?sitelink schema:inLanguage "nb".
  ?item p:P570 ?statement.
  ?statement ps:P570 ?death.
  ?statement prov:wasDerivedFrom ?refnode.
  OPTIONAL { ?refnode pr:P248 ?ref. }
  ?refnode pr:P854 ?refurl.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nb,en". }
    ?article schema:about ?item.
    ?article schema:isPartOf <https://no.wikipedia.org/>.
} 
}

Prøv!

Bilprodusenter

Brukte elementer: bilprodusent (Q786820), bilmerke (Q17412622)

Brukte egenskaper: forekomst av (P31), underklasse av (P279), land (P17), dato for etablering, fremstilling e.l. (P571), sluttdato (P582)

PREFIX schema: <http://schema.org/>

SELECT DISTINCT ?item ?itemLabel ?landLabel ?start ?slutt ?artikkel WHERE {
  {?item (wdt:P31/wdt:P279*) wd:Q786820.}
  UNION
  {?item (wdt:P31/wdt:P279*) wd:Q17412622.}
  OPTIONAL {?item wdt:P17 ?land . }
  OPTIONAL { ?item wdt:P571 ?start. }
  OPTIONAL { ?item wdt:P582 ?slutt. }
  OPTIONAL { ?artikkel schema:about ?item .
  ?artikkel schema:isPartOf <https://no.wikipedia.org/> .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nb,en,de,nl". }
}
ORDER BY (?itemLabel)
LIMIT 10000

Prøv!

Kart

Har geokoordinater innen et område, men har ikke noe land på Wikidata.

Brukte egenskaper: geokoordinater (P625), land (P17), ligger i administrativ enhet (P131), forekomst av (P31)

##defaultView:Map
SELECT ?item ?itemLabel ?ligger ?liggerLabel ?forekomst ?forekomstLabel ?location WHERE {
  SERVICE wikibase:box {
        ?item wdt:P625 ?location .
        bd:serviceParam wikibase:cornerWest "Point(10.0 68.0)"^^geo:wktLiteral .
        bd:serviceParam wikibase:cornerEast "Point(30.0 72.0)"^^geo:wktLiteral .
    }
  MINUS {?item wdt:P17 ?land}.
  OPTIONAL {?item wdt:P131 ?ligger }.
  OPTIONAL {?item wdt:P31 ?forekomst . }.
  ?article schema:about ?item .
  ?article schema:isPartOf <https://no.wikipedia.org/> .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nb,en". }
}
LIMIT 1000

Prøv!

Kart - Har kulturminne-ID, og koordinater, men ikke bilde på Wikidata.

Brukte egenskaper: Kulturminne-ID (P758), geokoordinater (P625), bilde (P18)

#defaultView:Map
SELECT ?q ?qLabel ?coords WHERE {
  ?q wdt:P758 ?kultid.
  ?q wdt:P625 ?coords.
  MINUS { ?q wdt:P18 _:b8. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

Prøv!

Kart - Har kulturminne-ID, fargelagt etter P31

Kart - Gater i Oslo fargelagt etter kjønn på hvem/hva den er oppkalt etter blå=mann, rød=kvinne, grønn=annet.

Brukte elementer: gate (Q79007), Oslo (Q585), mann (Q6581097), kvinne (Q6581072)

Brukte egenskaper: forekomst av (P31), ligger i administrativ enhet (P131), oppkalt etter (P138), kjønn (P21), geokoordinater (P625)

#defaultView:Map{ "rgb":"?rgb"}
SELECT ?item ?itemLabel ?hvem ?hvemLabel ?koord ?rgb  ?kjonnLabel WHERE {
  

  ?item wdt:P31 wd:Q79007.
  ?item wdt:P131 wd:Q585.
  OPTIONAL {?item wdt:P138 ?hvem. ?hvem wdt:P21 ?kjonn. }
  ?item wdt:P625 ?koord .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nb,sv,[AUTO LANGUAGE],en". }
  ?sitelink schema:about ?item.
  FILTER(REGEX(STR(?sitelink), "no.wikipedia.org/wiki/"))
  BIND(
        IF (!BOUND(?kjonn),  "000000",
        IF(?kjonn = wd:Q6581097, "0000bf",
            IF(?kjonn = wd:Q6581072, "ff0700","007f00")))
    AS ?rgb)
}

Prøv!

Kart - Verdensarvsteder for et gitt land. Her satt til Italia

Brukte elementer: Italia (Q38), Verdensarven (Q9259)

Brukte egenskaper: land (P17), kulturminnestatus (P1435), underklasse av (P279), geokoordinater (P625), bilde (P18)

#defaultView:Map
SELECT ?q ?qLabel ?coords ?landLabel ?img WHERE {
  ?q wdt:P17 wd:Q38.
  ?q (wdt:P1435/wdt:P279*) wd:Q9259.
  OPTIONAL { ?q wdt:P625 ?coords. }
  ?q wdt:P18 ?img.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nb,[AUTO_LANGUAGE],da,en,it". }
}

Prøv!

Kart - Verdensarvsteder. Sort - artikkel på no-wiki, rød - mangler artikkel på no-wiki

Brukte elementer: Italia (Q38), Verdensarven (Q9259)

Brukte egenskaper: land (P17), kulturminnestatus (P1435), underklasse av (P279), geokoordinater (P625), bilde (P18)

#defaultView:Map{ "rgb":"?rgb"}
SELECT ?q ?qLabel ?coords ?landLabel ?rgb   ?img WHERE {
#  ?q wdt:P17 wd:Q38.
  ?q (wdt:P1435/wdt:P279*) wd:Q9259.
  OPTIONAL { ?q wdt:P625 ?coords. }
  ?q wdt:P18 ?img.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nb,[AUTO_LANGUAGE],da,en,it". }
  OPTIONAL {
  ?article schema:about ?q .
  ?article schema:isPartOf <https://no.wikipedia.org/> .
    }
  BIND(
        IF (!BOUND(?article),  "ff0000", "000000")
    AS ?rgb)
}

Prøv!

Kart - Kirker i Danmark, minus Grønland. Sort - artikkel på no-wiki, rød - mangler artikkel på no-wiki, blå - mangler artikkel på no-wiki men flere sitelinks

Brukte elementer: Danmark (Q35), Grønland (Q223), kirkebygning (Q16970)

Brukte egenskaper: land (P17), forekomst av (P31), underklasse av (P279), geokoordinater (P625), bilde (P18)

PREFIX schema: <http://schema.org/>

#defaultView:Map{ "rgb":"?rgb"}
SELECT ?q ?qLabel ?coords ?landLabel ?rgb ?img ?sitelinks WHERE {
  ?q wdt:P17 wd:Q35.
  MINUS {?q wdt:P17 wd:Q223.}
  ?q (wdt:P31/wdt:P279*) wd:Q16970.
  OPTIONAL { ?q wdt:P625 ?coords. }
  OPTIONAL { ?q wdt:P18 ?img. }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nb,[AUTO_LANGUAGE],da,en,it". }
  OPTIONAL {
    ?article schema:about ?q.
    ?article schema:isPartOf <https://no.wikipedia.org/>.
  }
  ?q wikibase:sitelinks ?sitelinks.
  BIND(IF(BOUND(?article), "000000", IF (?sitelinks>=5,"0000ff","ff0000")) AS ?rgb)
}

Prøv!

Kart - Kraftverk av forskjellige typer

Brukte elementer: kraftverk (Q159719)

Brukte egenskaper: forekomst av (P31), underklasse av (P279), geokoordinater (P625), bilde (P18)

#defaultView:Map
SELECT DISTINCT ?object ?objectLabel ?coord ?layer ?img WHERE {
  ?object (wdt:P31/wdt:P279*) wd:Q159719.
  ?object wdt:P625 ?coord.
  OPTIONAL { ?object wdt:P18 ?img. }
  ?object wdt:P31 ?type.
  ?type wdt:P279* wd:Q159719.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?type rdfs:label ?layer.
  }
}

Prøv!

Kart - Byer uten artikkel på no-wiki, men med over 15 sitelinks.

Brukte elementer: by (Q515), Egypt (Q79)

Brukte egenskaper: forekomst av (P31), geokoordinater (P625), land (P17)

PREFIX schema: <http://schema.org/>

#defaultView:Map
SELECT ?item ?itemLabel ?linkcount ?coord WHERE {
  ?item wdt:P31 wd:Q515.
  ?item wdt:P625 ?coord.
  ?item wikibase:sitelinks ?linkcount.
#  ?item wdt:P17 wd:Q79.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nb,sv,[AUTO LANGUAGE],en". }
  OPTIONAL {
    ?article schema:about ?item.
    ?article schema:isPartOf <https://no.wikipedia.org/>.
  }
  FILTER(!BOUND(?article))
  FILTER(?linkcount > 15)
}

Prøv!

Personer med artikkel på bokmål men bare her

Brukte elementer: menneske (Q5)

Brukte egenskaper: forekomst av (P31), statsborgerskap (P27)

SELECT ?ident ?identLabel ?landLabel WHERE {
  ?ident wdt:P31 wd:Q5.
  ?ident wdt:P27 ?land.
  ?sitelink schema:about ?ident.
  ?sitelink schema:inLanguage "nb". 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nb","en". }
  ?ident wikibase:sitelinks ?linkcount.
  FILTER (?linkcount = 1)
}

Prøv!

Kurver

kurver - artikler på bokmål gitt år etter 1900 og kjønn

Brukte elementer: menneske (Q5), Norge (Q20), skiskytter (Q16029547)

Brukte egenskaper: forekomst av (P31), kjønn (P21), fødselsdato (P569), statsborgerskap (P27), beskjeftigelse (P106), underklasse av (P279)

#Articles in Norwegian (bokmål) per birth year after 1900 and gender
#defaultView:LineChart
SELECT ?gid (STR(SAMPLE(?year)) AS ?year) (COUNT(*) AS ?count) ?gender WHERE {
  ?pid wdt:P31 wd:Q5.
  ?pid wdt:P21 ?gid.
  ?pid wdt:P569 ?_date_of_birth.
#  ?pid wdt:P27 wd:Q20.  # uncomment to get Norwegians
#  ?pid (wdt:P106/wdt:P279*) wd:Q16029547.   # uncomment to get biathlete or subtype
  ?sitelink schema:about ?pid.
  ?sitelink schema:inLanguage "nb".
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?gid rdfs:label ?gender.
  }
  BIND(YEAR(?_date_of_birth) AS ?year)
  FILTER(?year > 1900)
}
GROUP BY ?gid ?gender ?year

Prøv!

kurver - artikler på bokmål gitt år etter 1900 og kjønn for musikere

Brukte elementer: Norge (Q20), menneske (Q5), musiker (Q639669)

Brukte egenskaper: statsborgerskap (P27), forekomst av (P31), kjønn (P21), fødselsdato (P569), beskjeftigelse (P106), underklasse av (P279)

#Articles in Norwegian (bokmål) per birth year after 1900 and gender
#defaultView:LineChart
#  ?pid wdt:P27 wd:Q20.  # uncomment to get Norwegians
SELECT ?gid (STR(SAMPLE(?year)) AS ?year) (COUNT(*) AS ?count) ?gender WHERE {
  ?pid wdt:P31 wd:Q5.
  ?pid wdt:P21 ?gid.
  ?pid wdt:P569 ?_date_of_birth.
  ?pid (wdt:P106/wdt:P279*) wd:Q639669.
  ?sitelink schema:about ?pid.
  ?sitelink schema:inLanguage "nb".
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?gid rdfs:label ?gender.
  }
  BIND(YEAR(?_date_of_birth) AS ?year)
  FILTER(?year > 1900)
}
GROUP BY ?gid ?gender ?year

Prøv!

kurver - artikler på fransk gitt år etter 1900 og kjønn for forfattere

Brukte elementer: menneske (Q5), forfatter (Q482980)

Brukte egenskaper: forekomst av (P31), kjønn (P21), fødselsdato (P569), beskjeftigelse (P106), underklasse av (P279)

#Articles in French per birth year after 1900 and gender
#defaultView:LineChart
SELECT ?gid (STR(SAMPLE(?year)) AS ?year) (COUNT(*) AS ?count) ?gender WHERE {
  ?pid wdt:P31 wd:Q5.
  ?pid wdt:P21 ?gid.
  ?pid wdt:P569 ?_date_of_birth.
  ?pid (wdt:P106/wdt:P279) wd:Q482980. #Author and subclass. Change occupation here 
  ?sitelink schema:about ?pid.
  ?sitelink schema:inLanguage "fr". #Change language for wiki here
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?gid rdfs:label ?gender.
  }
  BIND(YEAR(?_date_of_birth) AS ?year)
  FILTER(?year > 1900)
}
GROUP BY ?gid ?gender ?year

Prøv!

kurver - artikler på bokmål gitt år etter 1900 og kjønn for politikere

Brukte elementer: menneske (Q5), politiker (Q82955)

Brukte egenskaper: forekomst av (P31), kjønn (P21), fødselsdato (P569), beskjeftigelse (P106)

#Articles in Norwegian (bokmål) per birth year after 1900 and gender
#defaultView:LineChart
SELECT ?gid (STR(SAMPLE(?year)) AS ?year) (COUNT(*) AS ?count) ?gender WHERE {
  ?pid wdt:P31 wd:Q5.
  OPTIONAL { ?pid wdt:P21 ?gid. }
  ?pid wdt:P569 ?_date_of_birth.
  ?pid wdt:P106 wd:Q82955.
  ?sitelink schema:about ?pid.
  ?sitelink schema:inLanguage "nb".
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?gid rdfs:label ?gender.
  }
  BIND(YEAR(?_date_of_birth) AS ?year)
  FILTER(?year > 1900)
}
GROUP BY ?gid ?gender ?year

Prøv!

Dubletter

Samme bilde brukt to for to kirker på Wikidata. Fra Manske på Twitter - lettere utvidet med land og koordinat

Brukte elementer: kirkebygning (Q16970)

Brukte egenskaper: forekomst av (P31), bilde (P18), geokoordinater (P625), land (P17)

SELECT ?church ?churchLabel ?img ?coord ?countryLabel
WITH {
  SELECT ?church ?img WHERE {
    ?church wdt:P31 wd:Q16970 . 
    ?church wdt:P18 ?img .
  }
} AS %church_images
WHERE {
  {     
     SELECT ?img (count(?church) AS ?cnt)  {
       INCLUDE %church_images
     } GROUP BY ?img 
     HAVING (?cnt>1)
  }
  INCLUDE %church_images .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
    OPTIONAL {
    ?church wdt:P625 ?coord .
    ?church wdt:P17 ?country .
      }
}
ORDER BY desc(?cnt) ?img ?churchLabel

Prøv!

Diagram

diagram - Beskjeftigelse på norske statsborgere med artikkel på bokmål. Kan jo tenkes det er noe over skribenter på bokmål utenom no-wiki.

Brukte elementer: menneske (Q5), Norge (Q20)

Brukte egenskaper: forekomst av (P31), statsborgerskap (P27), beskjeftigelse (P106)

#defaultView:BubbleChart
SELECT ?occupation (COUNT(*) AS ?count)  WHERE {
  ?pid wdt:P31 wd:Q5.
  ?pid wdt:P27 wd:Q20 .
  ?sitelink schema:about ?pid.
  ?sitelink schema:inLanguage "nb".
  ?pid wdt:P106 ?occ.
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
    ?pid rdfs:label ?name.
    ?occ rdfs:label ?occupation.
  }
}
GROUP BY ?count ?occupation

Prøv!

Biografier utelukkende på no-wiki

Beskjeftigelse for biografier som ikke har andre prosjektlenker enn no-wiki (Ikke norske statsborgere):

Brukte elementer: menneske (Q5), Norge (Q20)

Brukte egenskaper: forekomst av (P31), statsborgerskap (P27), beskjeftigelse (P106)

#defaultView:BubbleChart
SELECT ?occupation (COUNT(*) AS ?count) WHERE {
  ?ident wdt:P31 wd:Q5.
  ?ident wdt:P27 ?land.
  MINUS {?ident wdt:P27 wd:Q20}
  ?ident wdt:P106 ?occ.
  ?sitelink schema:about ?ident.
  ?sitelink schema:inLanguage "nb". 
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "nb,[AUTO_LANGUAGE],en".
    ?ident rdfs:label ?name.
    ?occ rdfs:label ?occupation.
  }
  ?ident wikibase:sitelinks ?linkcount.
  FILTER (?linkcount = 1)
}GROUP BY ?count ?occupation

Prøv!

Statsborgerskap for biografier som ikke har andre prosjektlenker enn no-wiki (Ikke norske statsborgere):

Brukte elementer: menneske (Q5), Norge (Q20)

Brukte egenskaper: forekomst av (P31), statsborgerskap (P27), beskjeftigelse (P106)

#defaultView:BubbleChart
SELECT ?landnavn (COUNT(*) AS ?count) WHERE {
  ?ident wdt:P31 wd:Q5.
  ?ident wdt:P27 ?land.
  MINUS {?ident wdt:P27 wd:Q20}
  ?ident wdt:P106 ?occ.
  ?sitelink schema:about ?ident.
  ?sitelink schema:inLanguage "nb". 
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "nb,[AUTO_LANGUAGE],en".
    ?ident rdfs:label ?name.
    ?occ rdfs:label ?occupation.
    ?land rdfs:label ?landnavn
  }
  ?ident wikibase:sitelinks ?linkcount.
  FILTER (?linkcount = 1)
}GROUP BY ?count ?landnavn

Prøv!

Beskjeftigelse for biografier som har mindre enn 5 prosjektlenker (Ikke norske statsborgere):

Brukte elementer: menneske (Q5), Norge (Q20)

Brukte egenskaper: forekomst av (P31), statsborgerskap (P27), beskjeftigelse (P106)

#defaultView:BubbleChart
SELECT ?occupation (COUNT(*) AS ?count) WHERE {
  ?ident wdt:P31 wd:Q5.
  ?ident wdt:P27 ?land.
  MINUS {?ident wdt:P27 wd:Q20}
  ?ident wdt:P106 ?occ.
  ?sitelink schema:about ?ident.
  ?sitelink schema:inLanguage "nb". 
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "nb,[AUTO_LANGUAGE],en".
    ?ident rdfs:label ?name.
    ?occ rdfs:label ?occupation.
  }
  ?ident wikibase:sitelinks ?linkcount.
  FILTER (?linkcount < 5)
}GROUP BY ?count ?occupation

Prøv!

Petscan

Ca liste over stortingsrepresentanter uten infoboks

Artikler med infoboks som har både ektefelle og samboere

Søk etter norske skoler som har koord mal på no-wiki, men ingen koordinater på Wikidata

Skoler i Telemark med Infoboks skole, men uten kart

Ekstern informasjonssider om skoler søk hos Utdanningsdirektoratet

Artikler siste 7 dager uten Wikidata-statements (kjører ved klikk)

helt uten utsagn på Wikidata, utgangspunkt tor å legge inn noe

Har koordinater på no-wiki, men ikke på Wikidata. Kategorisert i kategorihierarkiet under Norge. (kjører ved klikk) 3950 pr 2018-10-09

Museum uten infoboks. (kjører ved klikk)

Museer i USA som mangler artikkel på no-wiki, har minst 8 sitelinks, ikke er markert på en-wiki for å mangle kilder

Museer i Tyskland som mangler artikkel på no-wiki, har minst 8 sitelinks, ikke er markert på en-wiki for å mangle kilder

Kandidater til infoboks biografi

Matematikere etter nasjonalitet

Personer etter beskjeftigelse og nasjonalitet

referanser

Disse kan brukes til å legge inn referanse-URL til Stortinget på fødselsdato. Legg den samme til på verv, parti, fødested og annet som stortingsbiografien har.

Medlemmer av Regjeringen Solberg som ikke har referanse på fødselsdato via referanseurl (22 per 2018-08-29, 0 per 2018+09+02)

Medlemmer av Regjeringen Stoltenberg 2 som ikke har referanse på fødselsdato via referanseurl (38 per 2018-08-29)

Stortingsrepresentanter 2017–2021 som ikke har referanse på fødselsdato via referanseurl (153 per 2018-08-29)

Stortingsrepresentanter som ikke har referanse på dato for dødsfall, men er i kategori for avdøde (1354 per 2018-12-7)

Stortingsrepresentanter som har referanse på dato for dødsfall (321 per 2018-12-7)

Andre

Norske barnebokforfattere som ikke har referanse-URL for fødselsdato

Kvinnelige norske fotballspillere som ikke har referanse for fødselsdato med unntak av import (297 per 2018-12-06)

Mannlige norske fotballspillere som ikke har referanse for fødselsdato med unntak av import (1253 per 2018-12-06)

kortlenker til wikidatasøk

Redigering på Wikidata

Kulturminne-ID uten Forekomst av

Legge inn referanser for stortingsrepresentanter som har biografi på stortinget.no

Det finnes et par utvidelser på Wikidata som er nyttige.

Kopier referanser - Legger til ei lenke for å kopiere referanser og legge dem til på andre egenskaper i samme element.
CurrentDate - Automatically adds the date of today while using the property besøksdato (P813).

Jeg legger inn referansene med referanse-URL (P854) til biografisiden og besøksdato (P813).

Legger inn referanse på kjønn, hvis det står sønn/datter av ...
Fødselsdato/sted. Dødsdato, men sted står ikke det jeg har sett.
Politiker.
Stortingsrepresentant, hvis det står i biografien. (Regjeringsmedlemmer kan ha biografi også)
Vararepresentant tilsvarende.
Regjeringsmedlemsskap hvis relevant.
Parti. Står helt øverst, men også bak hver stortingsperiode.
Noen utmerkelser kan være nevnt og også utdannelse, men det er ofte ikke utdannelsessted som står på stortinget.no.

Sjekker samsvar mellon det som er i Wikidata og biografien.

Lister over stortingsrepresentanter som ikke har referanser finnes her (kjøres automatisk):

perioden 2017-2021. Per 14. september 115. Per 14. september 0.
perioden 2013-2017. Per 2. september 123. Per 14. september 59.
perioden 2009-2013. Per 2. september 121. Per 14. september 91.

OSM

skoler uten wikidata-tag på interaktivt kart

(
  way
    ["amenity"="school"][!"wikidata"]({{bbox}})
    ;  
  relation
    ["amenity"="school"][!"wikidata"]({{bbox}})
    ;
);
(._;>;);
out;

naturreservater uten wikidata-tag på interaktivt kart

( way ["leisure"="nature_reserve"][!"wikidata"]({{bbox}}) ; relation ["leisure"="nature_reserve"][!"wikidata"]({{bbox}}) ; ); (._;>;); out;

Gater uten wikidata-tag på interaktivt kart

[out:json][timeout:25];
// gather results
(
  way["highway"][name][!wikidata]({{bbox}});
  relation["highway"][name][!wikidata]({{bbox}});
);
// print results
out body;
>;
out skel qt;

Annet

Bilder fra operaen i Oslo

Interiør fra den nye operaen i Oslo
Olafur Einarssons kunstneriske utsmykking i foajeen
Utsikten fra balkong
Foajeen
Trapp opp til balkongplassene
Gang i retning av balkongplassene og utsikt
Gangen sett tilbake mot trappen
Balkongen på utsiden av salen
Balkongene speiler seg i vinduet mot fjorden
Norges største lysekrone i taket på hovedsenens sal
Salen med 1358 sitteplasser
Publikum på vei opp trappen fra inngangen. Tatt under akustikktesten.
Salen klar til akustikktest
Salen sett fra andre balkong
Fra taket av operahuset
Operaen sett fra sjøen
En mulighet til å dyppe tærne i Oslofjorden mens man er på operaens tak
Under bygging en dag i februar

Mal:NavStart Mal:NavStart Mal:NavStart

Salen med en triumfbue ut mot hovedinngangen
Vestveggen i salen
Poseidon
Fra vestveggen

Mal:NavSlutt Mal:NavSlutt Mal:NavSlutt Mal:NavStart Mal:NavStart

Taj Mahal
Taj Mahal
Detalj
Detalj
Detalj
Detalj
Detalj
Detalj
Detalj

Mal:NavSlutt Mal:NavSlutt

pyb

pwb.py replace -regex "\{\{\s*[Kk]oord\s*\|.+?\|\s*vis\s*=\s*tittel\s*\}\}\n?" "" "\s*\|\s*koord\s*=\s*\{\{\s*[Kk]oord\s*\|.+?\|\s*vis\s*=\s*tekst,tittel\s*\}\}\n?" "\n" "\{\{\s*[Kk]oord\s*\|.+?\|\s*vis\s*=\s*tittel\|.+\}\}\n?" "" "\{\{\s*[Kk]oord\s*\|.+?\|\s*display\s*=\s*title\s*\}\}\n?" ""  -cat:"Artikler med lokal koord mal til tittelfelt" -summary:"bot: Fjerner overflødig {{koord}}" -limit:1450

pwb.py replace -regex "\n?\|\s*(kart|koord|koord geo|koordinater)\s*=\s*\{\{\s*[Kk]oord\s*\|.+?\}\}" ""  -cat:"Artikler med lokal koord mal til tittelfelt" -summary:"bot: Fjerner overflødig {{koord}}" -limit:100

pwb.py replace -regex "\{\{\s*[Kk]oord\s*\|.+?\|\s*display\s*=\s*title\|.+s*\}\}\n?" "" -cat:"Artikler med lokal koord mal til tittelfelt" -summary:"bot: Fjerner overflødig {{koord}}" -limit:100

pwb.py replace -regex "\{\{\s*[Kk]oord\s*\|.+?\|\s*(display|vis)\s*=\s*(tittel|title)\s*\}\}\n?" "" "\s*\|\s*koord\s*=\s*\{\{\s*[Kk]oord\s*\|.+?\|\s*vis\s*=\s*tekst,tittel\s*\}\}\n?" "\n" "\{\{\s*[Kk]oord\s*\|.+?\|\s*vis\s*=\s*tittel\|.+\}\}\n?" "" "\{\{\s*[Kk]oord\s*\|.+?\|\s*display\s*=\s*title\s*\}\}\n?" ""  -cat:"Artikler med lokal koord mal til tittelfelt" -summary:"bot: Fjerner overflødig {{koord}}" -limit:450

kraftverk - verden - sparql - kart

overpass-turbo query

/*
This query looks for nodes, ways or relations 
with the given key/value combination.
Choose your region and hit the Run button above!
*/
[out:json][timeout:25];
// gather results
(
  // query part for: “type=waterway”
  relation["waterway"="river"][!wikidata]({{bbox}});
);
// print results
out body;
>;
out skel qt;

[out:json][timeout:25];
{{geocodeArea:Norge}}->.searchArea;
// gather results
(
  // query part for: “leisure=nature_reserve”
//  way[leisure=nature_reserve][!wikidata](area.searchArea);
  relation[waterway=river][wikidata](area.searchArea);
);
// print results
out center tags body;

[out:json][timeout:25];
{{geocodeArea:Norge}}->.searchArea;
// gather results
(
  // query part for: “leisure=nature_reserve”
  way[leisure=nature_reserve][!wikidata](area.searchArea);
  relation[leisure=nature_reserve][!wikidata](area.searchArea);
);
// print results
out center tags body;

/*
This query looks for nodes, ways and relations 
with the given key/value combination.
Choose your region and hit the Run button above!
*/
[out:json][timeout:25];
{{geocodeArea:Norge}}->.searchArea;
// gather results
(
  // query part for: “leisure=nature_reserve”
  way[leisure=nature_reserve][!wikidata](area.searchArea);
  relation[leisure=nature_reserve][!wikidata](area.searchArea);
);
// print results
out body;
>;
out skel qt;

Innsjø i en kommune gitt et kommunenr

Brukte elementer: innsjø (Q23397), vannmagasin (Q131681), kunstig dam (Q3253281)

Brukte egenskaper: forekomst av (P31), underklasse av (P279), ligger i administrativ enhet (P131), norsk kommunenummer (P2504), NVE Innsjødatabase-ID (P5079), GNS-ID (P2326), GeoNames-identifikator (P1566), geokoordinater (P625), SSR stedsnummer (P1850)

SELECT ?item ?label ?ssr ?nveid ?gnsid ?geonamesid ?loc ?forekomstLabel ?article ## Kan byttes ut med * for å få alle data
{
  {
    SELECT distinct * {
      {?item wdt:P31/wdt:P279* wd:Q23397. }## søker her etter innsjø (Q23397) og alt som er underklasser (rekursivt) av innsjø
     UNION
      { ?item wdt:P31/wdt:P279* wd:Q131681. }
     UNION
      { ?item wdt:P31/wdt:P279* wd:Q3253281. }

 #     ?item wdt:P31 ?forekomst.
      ?item wdt:P131 ?kommune. ##Ligger i en kommune
      ?kommune wdt:P2504 "5601". ##Denne kommunen har norsk kommunenr som skal være det som er gitt som en streng
      optional {
        ?item wdt:P5079 ?nveid . #NVE Innsjødatabase-ID (P5079)
      }
      optional {
        ?item wdt:P2326 ?gnsid . #GNS-ID (P2326)
      }
      optional {
        ?item wdt:P1566 ?geonamesid . #GeoNames-identifikator (P1566)
      }
        optional {
        ?item wdt:P625 ?loc . #Geografisk posisjon 
      }
      optional {
        ?item  wdt:P1850 ?ssr. #SSR stedsnummer (P1850)
      }
      OPTIONAL {
        ?article schema:about ?item.   #artikkel 
        ?article schema:isPartOf <https://no.wikipedia.org/>. #Begrenset til no.wikipedia
      }
 
    } LIMIT 10000 
  }
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "nb,en,de,fr,ja,es,ru,pt,it,zh,fa,ar,pl,nl,uk,tr,id,he,cs,sv,hu,fi,vi,ko,el,hi,bn,no,ca,ro,th,da,sr,bg,az,ms,et,uz,hr,sk,eu,hy,sl,lt,eo,ta,kk,lv,be,kn,sq,ur,mk" .
    ?item rdfs:label ?label . ?item schema:description ?description. ?forekomst rdfs:label ?forekomstLabel
  }
}

Prøv!

Dette er en Wikipedia-brukerside / This is a Wikipedia user page

Hvis du finner denne siden noe annet sted enn Wikipedia, så er det et speilsted. Vær oppmerksom på at siden kan være utdatert og at brukeren som eier siden ikke nødvendigvis har noen personlig tilknytning til andre steder enn Wikipedia selv. Originalsiden finnes på http://no.wikipedia.org/wiki/Bruker:Haros

If you find this page on any site other than Wikipedia, you are viewing a mirror site. Be aware that the page may be outdated, and that the user this page belongs to may have no personal affiliation with any site other than Wikipedia itself. The original page is located at http://no.wikipedia.org/wiki/Bruker:Haros

Wikimedia Foundation